home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Best of Shareware
/
Best of PC Windows Shareware 1.0 - Wayzata Technology (7111) (1993).iso
/
pc
/
dos
/
programg
/
zi_123
/
demo.zsl
< prev
next >
Wrap
Text File
|
1992-08-19
|
10KB
|
464 lines
;
; Sample Script for Z/Install Ver 1.0 - (c) 1992 SpeedSoft
;
; This is the actual script used to install Z/Install.
;
; Release version: 1.0
; date : 07/01/92
;
[disks]
; Number:Label of disk:Disk description (spaces NOT allowed between fields)
1:INSTALL001:Z/Install installation disk
[end]
[paths]
; Number:Path
; Note that path 0 is also accessible by the variable name 'RootDir'
0:\\ZINSTALL
1:\\SAMPLES
2:\\DOC
3:\\OPTDIST
4:\\ZPACK
[end]
[FILES]
ZPACK.ZPK:4:1:1:4
MAIN.ZPK:0:1:1:1
DOCS.ZPK:2:1:1:3
OPTDIST.ZPK:3:1:1:2
SAMPLES.ZPK:1:2:1:5
[END]
; *** Setting up Z/Install
SetDialogColor BrightBrownOnBrightBlue
SetDialogStyle Single
SetBackColor WhiteOnBlue
SetBackChar 176
SetPrintColor BrightWhiteOnBrightBlue
SetInputColor BrightWhiteOnBlack
SetInputFill 250
SetInputCaps On
SetInputTplate "**************************************************"
SetExitMessage "Thanks for choosing Z/Install!"
SetExplode Dialog_Warn
SetImplode Dialog_Only
SetExplodeSnd Off ; No sound on explode
SetExplodeType 2 ; Fast explosions
MarkFilesTime 0, 0, 0
MarkFilesDate 8, 3, 92
SetDescLine 19
SetBarNormalColor WhiteOnBrightBlue
SetBarHighColor BlueOnBrightWhite
SetBarCharColor BrightRedOnBrightBlue
HiBack
Gosub ClearScr
; *** End Setting Up Z/Install
Dialog 0, 0 @(0,5)
@CWelcome to Z/Install v1.0! This installation program will guide
@Cyou through the simple steps required to copy Z/Install to your
@Csystem. After the installation is complete, you will have the
@Coption of seeing a demonstration of the capabilities of Z/Install.
EndDialog
CheckInstallOK
Int Menuchoice = 1
Str Over = "Overwrite"
Overwriteall = 1
InstDrv = "C"
GoSub ClearScr
Label MenuLoop
BarMenu Menuchoice, 50, Menuchoice, 0
~Choose Destination Disk [%InstDrv%:]
: Choose the disk to install on.
Choose ~Destination Dir [%RootDir%]
: Choose the directory to install to.
Toggle ~Overwrite Mode [%over%]
: Toggle Overwrite Mode
~Begin Installation
: Begin the installation
EndBarMenu
if Menuchoice = 1
Gosub ChooseDisk
Elif Menuchoice = 2
Gosub ChooseDir
Elif Menuchoice = 3
Gosub ToggleOver
Else
Gosub BeginInst
Endif
Goto MenuLoop ; Loop back and redo the menu
; *****************************************************************************
; Choose destination drive.
; *****************************************************************************
Label ChooseDisk
Gosub ClearScr
Dialog 0, 1 @(0,3)
@CPlease choose the fixed disk that you would like to
@Cinstall the program on.
EndDialog
GetInstallationDrive @(0,11)
GoSub ClearScr
Return
; *****************************************************************************
; Choose destination dir.
; *****************************************************************************
Label ChooseDir
Dialog 0, 1 @(0,6)
@CEnter the path on drive %Instdrv%: in which to install the program:
@ERootdir
EndDialog
Return
; *****************************************************************************
; Toggle Overwrite
; *****************************************************************************
Label ToggleOver
If Overwriteall = 1
Overwriteall = 0
Over = "Don't Overwrite"
Else
Overwriteall = 1
Over = "Overwrite"
Endif
Return
; ****************************************************************************
; Clear screen
; ****************************************************************************
Label ClearScr
ClrScr
WriteScreen BlackOnWhite, 0, 1, " Z/Install installation program "
WriteScreen BlackOnWhite, 0, 25, " Press <ESC> to exit anytime "
Return
; ****************************************************************************
; Begin installation
; ****************************************************************************
Label BeginInst
Dialog 0, 0 @(0,6)
" Install will now copy the files to your hard disk"
" using the following parameters:"
" Path - %Rootdir%"
" Drive - %Instdrv%:"
" Press <ESC> to abort Install, or any other key to continue."
EndDialog
BeginInstall
Gosub ClearScr
int choice
str yn
Dialog 0, 1 @(0,3)
@CZ/Install is finished installing on your system!
" In order for Z/Install to run correctly, the following"
" lines must be in your CONFIG.SYS:"
" FILES = 20"
" BUFFERS = 10 (Increases performance of the compiler,"
" but is not necessary)"
" And, optionally, your AUTOEXEC.BAT can have its PATH"
" statement pointing to %instdrv%:%rootdir%."
" Press 'Y' if you would like INSTALL to modify your boot"
" files for you, or 'N' if you would like to edit them"
" yourself."
@CEnter your choice:
EndDialog
yn = getchoice "YN"
If yn = "Y"
SetFiles 50
SetBuffers 10
ModPath Instdrv, ":", Rootdir
Else
InterLoad Instdrv, ":\\CONFIG.SYS"
InterPut "BUFFERS=10"
InterPut "FILES=50"
InterEdit
InterLoad Instdrv, ":\\AUTOEXEC.BAT"
InterPut "PATH %PATH%;", Instdrv, ":", Rootdir
InterEdit
Endif
GoSub ClearScr
Dialog 0, 1 @(0,7)
@CYou now have the option of taking a guided tour through
@Cthe features of Z/Install.
EndDialog
BarMenu choice, 40, 1, 1 @(0,15)
~Yes! I want to go on a guided tour!
~No. Let me go now and I'll do it later.
EndBarMenu
if choice = 2
GoSub Exit
endif
SetDialogColor BrightWhiteOnCyan
SetDialogStyle Double
SetBackColor BlackOnBlue
SetBackChar 32
SetPrintColor BrightBlackOnCyan
SetInputColor BrightWhiteOnBlack
SetInputFill 250
SetInputCaps Off
SetInputTplate "**************************************************"
Gosub ClearScr
Dialog 0, 0
@CWelcome to the Z/Install guided tour! Over the next few minutes,
@Cyou'll be introduced to some of the features of Z/Install. If you
@Cwish to exit the tour at any time, simply press the <ESC> key.
EndDialog
str v_ega
if VgaEga = 2
v_ega = "VGA"
elif VgaEga = 1
v_ega = "EGA"
else
v_ega = "Probably CGA"
endif
str joystr = "Yes"
if Joystick = 0
joystr = "No"
endif
str mcpu = "Yes"
if MathCPU = 0
mcpu = "No"
endif
str ansistr = "Yes"
if ANSISYS = 0
ansistr = "No"
endif
int net = NetworkType
str netstr = "No network"
if net = 1
netstr = "Novell"
elif net = 2
netstr = "NetBIOS Network"
endif
Dialog 0, 0 @(0,3)
@CFirst, we'll explore some of Z/Install's auto-detection features.
Here is your system configuration:
Processor type : %ProcessorType%
XMS Memory : %XMSMemory% kbytes
EMS Memory : %EMSMemory% kbytes
Conv. Memory : %ConvMemory% kbytes
Extended Memory: %ExtendedMemory% kbytes
VGA/EGA : %v_ega%
Joystick? : %joystr%
Math CoPro? : %mcpu%
File handles : %FileHandles%
Buffers : %Buffers%
DOS Version : %OSMajor%.%OSMinor%
ANSI.SYS? : %ansistr%
Network : %netstr%
EndDialog
SetBackChar 177
Gosub ClearScr
SetExplodeSnd On
Dialog 50, 0
@CExploding windows with ))) sound (((
EndDialog
SetExplodeSnd Off
SetDialogColor BrightWhiteOnBlue
SetPrintColor BrightWhiteOnBlue
Gosub ClearScr
Dialog 30, 1 @(2,3)
@CYou can have...
EndDialog
SetDialogColor BrightWhiteOnRed
SetPrintColor BrightWhiteOnRed
Dialog 30, 1 @(20,8)
@CMultiple Windows...
EndDialog
SetDialogColor BlackOnBrightCyan
SetPrintColor BlackOnBrightCyan
Dialog 30, 1 @(40,13)
@COn the screen...
EndDialog
SetDialogColor BrightBlueOnWhite
SetPrintColor BrightBlueOnWhite
Dialog 30, 0 @(25,18)
@CAt the same time!
EndDialog
Gosub ClearScr
SetExplode None
int x = 2
int y = 3
label loop
dialog 20, 1 @(x,y)
@CDialog!
enddialog
x+=2
y++
if y > 16
goto continue
endif
goto loop
label continue
SetDialogColor BrightWhiteOnBlue
SetPrintColor BrightWhiteOnBlue
SetExplode Dialog_Warn
Dialog 30, 0
@CFassssst....
EndDialog
Gosub ClearScr
SetDialogColor BrightWhiteOnBlue
SetPrintColor BrightBrownOnBlue
Dialog 0, 0
@CZ/Install offers Security!
@CIf you wish, Z/Install will check to make sure that your application
@Cis being installed from a hard disk. Even SUBSTed and ASSIGNed disks
@Cdon't fool Z/Install! This is a great feature for making the piracy
@Cof your application all the more awkward. The distribution disk
@Cbuilder will even 'brand' your floppies so that they can't be copied
@Cor archived for modem transfer (much of today's piracy is
@Cdone through Bulletin Board Systems).
EndDialog
Dialog 0, 0
@CZ/Install is Eye-Catching!
@CExploding windows with sound, snazzy colors, speed and grace:
@CZ/Install has it all!
EndDialog
Dialog 0, 0
@CNow that you've gotten a feel for some of Z/Install's features,
@Ctake the time to browse through Chapter 1 in the user's manual.
@CWe hope you find using Z/Install fun and productive.
@CDon't hesitate to call with any questions or promblems that you
@Cmay encounter!
EndDialog
Label Exit
SetDisk InstDrv
ChDir RootDir